Merge pull request #2087 from pchaigno/case-sensitivity

Detection by extension made case-insensitive

samples/Eiffel/application.e

@@ -0,0 +1,44 @@
+note
+	description : "nino application root class"
+	date        : "$Date$"
+	revision    : "$Revision$"
+
+class
+	APPLICATION
+
+inherit
+	ARGUMENTS
+
+	HTTP_SERVER_SHARED_CONFIGURATION
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make
+			-- Run application.
+		local
+			l_server : HTTP_SERVER
+			l_cfg: HTTP_SERVER_CONFIGURATION
+			l_http_handler : HTTP_HANDLER
+		do
+			create l_cfg.make
+			l_cfg.http_server_port := 9_000
+			l_cfg.document_root := default_document_root
+			set_server_configuration (l_cfg)
+			debug ("nino")
+				l_cfg.set_is_verbose (True)
+			end
+
+			create l_server.make (l_cfg)
+			create {APPLICATION_CONNECTION_HANDLER} l_http_handler.make (l_server)
+			l_server.setup (l_http_handler)
+		end
+
+feature -- Access
+
+	default_document_root: STRING = "webroot"
+
+end
+

samples/Eiffel/book_collection.e

@@ -0,0 +1,82 @@
+class
+	BOOK_COLLECTION
+
+create
+	make
+
+feature {NONE} -- Initialization
+
+	make (a_name: STRING_32)
+			-- Create a book collection with `a_name' as `name'.
+		do
+			set_name (a_name)
+			create book_index.make (10)
+		ensure
+			name_set: name = a_name
+		end
+
+feature -- Access
+
+	name: STRING_32
+			-- Name.
+
+	books: LIST [BOOK]
+			-- collection of book.
+		do
+			create {LINKED_LIST [BOOK]} Result.make
+			across
+				book_index as it
+			loop
+				Result.append (it.item)
+			end
+		end
+
+	books_by_author (a_author: STRING_32): LIST [BOOK]
+			-- Books wrote by `a_author' in this collection.
+		do
+			if attached book_index [a_author] as l_result then
+				Result := l_result
+			else
+				create {LINKED_LIST [BOOK]} Result.make
+			end
+		end
+
+feature -- Change
+
+	set_name (a_name: STRING_32)
+			-- Set `name' with `a_name'.
+		do
+			name := a_name
+		ensure
+			name_set: name = a_name
+		end
+
+	add_book (a_book: BOOK)
+			-- Extend collection with `a_book'.
+		local
+			l: detachable LIST [BOOK]
+		do
+			l := book_index.at (a_book.author.name)
+			if l = Void then
+				create {LINKED_LIST [BOOK]} l.make
+				book_index.put (l, a_book.author.name)
+			end
+			l.force (a_book)
+		end
+
+	add_books (book_list: like books)
+			-- Append collection with `book_list'.
+		do
+			across
+				book_list as it
+			loop
+				add_book (it.item)
+			end
+		end
+
+feature {NONE} -- Implementation
+
+	book_index: HASH_TABLE [LIST [BOOK], STRING_32]
+			-- Association of author name and its books.
+
+end -- class BOOK_COLLECTION

samples/Eiffel/git_checkout_command.e

@@ -0,0 +1,41 @@
+note
+	description: "Git checkout command."
+	author: "Olivier Ligot"
+
+class
+	GIT_CHECKOUT_COMMAND
+
+inherit
+	GIT_COMMAND
+
+create
+	make,
+	make_master
+
+feature {NONE} -- Initialization
+
+	make (a_branch: STRING)
+			-- Checkout the branch `a_branch'.
+		do
+			initialize
+			arguments.force_last (a_branch)
+			branch := a_branch
+		ensure
+			branch_set: branch = a_branch
+		end
+
+	make_master
+			-- Checkout the master branch.
+		do
+			make ("master")
+		end
+
+feature -- Access
+
+	branch: STRING
+			-- Branch to checkout
+
+	name: STRING = "checkout"
+			-- Git subcommand name
+
+end